home *** CD-ROM | disk | FTP | other *** search
/ The Arsenal Files 8 / The Arsenal Files Collection #8 (Arsenal Computer) (1996).ISO / g_quake / monsev10.zip / COMBAT.QC < prev    next >
Text File  |  1996-09-02  |  7KB  |  295 lines
  1.  
  2. void() T_MissileTouch;
  3. void() info_player_start;
  4. void(entity targ, entity attacker) ClientObituary;
  5.  
  6. void() monster_death_use;
  7.  
  8. //============================================================================
  9.  
  10. /*
  11. ============
  12. CanDamage
  13.  
  14. Returns true if the inflictor can directly damage the target.  Used for
  15. explosions and melee attacks.
  16. ============
  17. */
  18. float(entity targ, entity inflictor) CanDamage =
  19. {
  20. // bmodels need special checking because their origin is 0,0,0
  21.     if (targ.movetype == MOVETYPE_PUSH)
  22.     {
  23.         traceline(inflictor.origin, 0.5 * (targ.absmin + targ.absmax), TRUE, self);
  24.         if (trace_fraction == 1)
  25.             return TRUE;
  26.         if (trace_ent == targ)
  27.             return TRUE;
  28.         return FALSE;
  29.     }
  30.     
  31.     traceline(inflictor.origin, targ.origin, TRUE, self);
  32.     if (trace_fraction == 1)
  33.         return TRUE;
  34.     traceline(inflictor.origin, targ.origin + '15 15 0', TRUE, self);
  35.     if (trace_fraction == 1)
  36.         return TRUE;
  37.     traceline(inflictor.origin, targ.origin + '-15 -15 0', TRUE, self);
  38.     if (trace_fraction == 1)
  39.         return TRUE;
  40.     traceline(inflictor.origin, targ.origin + '-15 15 0', TRUE, self);
  41.     if (trace_fraction == 1)
  42.         return TRUE;
  43.     traceline(inflictor.origin, targ.origin + '15 -15 0', TRUE, self);
  44.     if (trace_fraction == 1)
  45.         return TRUE;
  46.  
  47.     return FALSE;
  48. };
  49.  
  50.  
  51. /*
  52. ============
  53. Killed
  54. ============
  55. */
  56. void(entity targ, entity attacker) Killed =
  57. {
  58.     local entity oself;
  59.  
  60.     oself = self;
  61.     self = targ;
  62.     
  63.     if (self.health < -99)
  64.         self.health = -99;        // don't let sbar look bad if a player
  65.  
  66.     if (self.movetype == MOVETYPE_PUSH || self.movetype == MOVETYPE_NONE)
  67.     {    // doors, triggers, etc
  68.         self.th_die ();
  69.         self = oself;
  70.         return;
  71.     }
  72.  
  73.     self.enemy = attacker;
  74.  
  75. // bump the monster counter
  76.     if (self.flags & FL_MONSTER)
  77.     {
  78.         killed_monsters = killed_monsters + 1;
  79.         WriteByte (MSG_ALL, SVC_KILLEDMONSTER);
  80.     }
  81.  
  82.     ClientObituary(self, attacker);
  83.     
  84.     self.takedamage = DAMAGE_NO;
  85.     self.touch = SUB_Null;
  86.  
  87.     monster_death_use();
  88.     self.th_die ();
  89.     
  90.     self = oself;
  91. };
  92.  
  93.  
  94. /*
  95. ============
  96. T_Damage
  97.  
  98. The damage is coming from inflictor, but get mad at attacker
  99. This should be the only function that ever reduces health.
  100. ============
  101. */
  102. void(entity targ, entity inflictor, entity attacker, float damage) T_Damage=
  103. {
  104.     local    vector    dir;
  105.     local    entity    oldself;
  106.     local    float    save;
  107.     local    float    take;
  108.  
  109.     if (!targ.takedamage)
  110.         return;
  111.  
  112. // used by buttons and triggers to set activator for target firing
  113.     damage_attacker = attacker;
  114.  
  115. // check for quad damage powerup on the attacker
  116.     if (attacker.super_damage_finished > time)
  117.         damage = damage * 4;
  118.  
  119. // save damage based on the target's armor level
  120.  
  121.     save = ceil(targ.armortype*damage);
  122.     if (save >= targ.armorvalue)
  123.     {
  124.         save = targ.armorvalue;
  125.         targ.armortype = 0;    // lost all armor
  126.         targ.items = targ.items - (targ.items & (IT_ARMOR1 | IT_ARMOR2 | IT_ARMOR3));
  127.     }
  128.     
  129.     targ.armorvalue = targ.armorvalue - save;
  130.     take = ceil(damage-save);
  131.  
  132. // add to the damage total for clients, which will be sent as a single
  133. // message at the end of the frame
  134. // FIXME: remove after combining shotgun blasts?
  135.     if (targ.flags & FL_CLIENT)
  136.     {
  137.         targ.dmg_take = targ.dmg_take + take;
  138.         targ.dmg_save = targ.dmg_save + save;
  139.         targ.dmg_inflictor = inflictor;
  140.     }
  141.  
  142. // figure momentum add
  143.     if ( (inflictor != world) && (targ.movetype == MOVETYPE_WALK) )
  144.     {
  145.         dir = targ.origin - (inflictor.absmin + inflictor.absmax) * 0.5;
  146.         dir = normalize(dir);
  147.         targ.velocity = targ.velocity + dir*damage*8;
  148.     }
  149.  
  150. // check for godmode or invincibility
  151.     if (targ.flags & FL_GODMODE)
  152.         return;
  153.     if (targ.invincible_finished >= time)
  154.     {
  155.         if (self.invincible_sound < time)
  156.         {
  157.             sound (targ, CHAN_ITEM, "items/protect3.wav", 1, ATTN_NORM);
  158.             self.invincible_sound = time + 2;
  159.         }
  160.         return;
  161.     }
  162.  
  163. // team play damage avoidance
  164.     if ( (teamplay == 1) && (targ.team > 0)&&(targ.team == attacker.team) )
  165.         return;
  166.         
  167. // do the damage
  168.     targ.health = targ.health - take;
  169.             
  170.     if (targ.health <= 0)
  171.     {
  172.         Killed (targ, attacker);
  173.         return;
  174.     }
  175.  
  176. // react to the damage
  177.     oldself = self;
  178.     self = targ;
  179.  
  180.     if ( (self.flags & FL_MONSTER) && attacker != world)
  181.     {
  182.               if (self != attacker)
  183.               {
  184.                     if (self.health <= self.crit)
  185.                     {
  186.                          self.avoid = attacker;  //SCC.  Avoid he that
  187.                     }                            //injured you if health low. 
  188.                     else                         
  189.                     {                                   
  190.                          if (attacker != self.enemy)
  191.                          {
  192.                               if ( (self.classname != attacker.classname)
  193.                               || (self.classname == "monster_army" ) )
  194.                               {
  195.                                    if (self.enemy.classname == "player")
  196.                                          self.oldenemy = self.enemy;
  197.                                          self.enemy = attacker;
  198.                                          FoundTarget ();
  199.                               }
  200.                          }
  201.                    }
  202.               }
  203.         }
  204.  
  205.     if (self.th_pain)
  206.     {
  207.         self.th_pain (attacker, take);
  208.     // nightmare mode monsters don't go into pain frames often
  209.         if (skill == 3)
  210.             self.pain_finished = time + 5;        
  211.     }
  212.  
  213.     self = oldself;
  214. };
  215.  
  216. /*
  217. ============
  218. T_RadiusDamage
  219. ============
  220. */
  221. void(entity inflictor, entity attacker, float damage, entity ignore) T_RadiusDamage =
  222. {
  223.     local    float     points;
  224.     local    entity    head;
  225.     local    vector    org;
  226.  
  227.     head = findradius(inflictor.origin, damage+40);
  228.     
  229.     while (head)
  230.     {
  231.         if (head != ignore)
  232.         {
  233.             if (head.takedamage)
  234.             {
  235.                 org = head.origin + (head.mins + head.maxs)*0.5;
  236.                 points = 0.5*vlen (inflictor.origin - org);
  237.                 if (points < 0)
  238.                     points = 0;
  239.                 points = damage - points;
  240.                 if (head == attacker)
  241.                     points = points * 0.5;
  242.                 if (points > 0)
  243.                 {
  244.                     if (CanDamage (head, inflictor))
  245.                     {    // shambler takes half damage from all explosions
  246.                         if (head.classname == "monster_shambler")                        
  247.                             T_Damage (head, inflictor, attacker, points*0.5);
  248.                         else
  249.                             T_Damage (head, inflictor, attacker, points);
  250.                     }
  251.                 }
  252.             }
  253.         }
  254.         head = head.chain;
  255.     }
  256. };
  257.  
  258. /*
  259. ============
  260. T_BeamDamage
  261. ============
  262. */
  263. void(entity attacker, float damage) T_BeamDamage =
  264. {
  265.     local    float     points;
  266.     local    entity    head;
  267.     
  268.     head = findradius(attacker.origin, damage+40);
  269.     
  270.     while (head)
  271.     {
  272.         if (head.takedamage)
  273.         {
  274.             points = 0.5*vlen (attacker.origin - head.origin);
  275.             if (points < 0)
  276.                 points = 0;
  277.             points = damage - points;
  278.             if (head == attacker)
  279.                 points = points * 0.5;
  280.             if (points > 0)
  281.             {
  282.                 if (CanDamage (head, attacker))
  283.                 {
  284.                     if (head.classname == "monster_shambler")                        
  285.                         T_Damage (head, attacker, attacker, points*0.5);
  286.                     else
  287.                         T_Damage (head, attacker, attacker, points);
  288.                 }
  289.             }
  290.         }
  291.         head = head.chain;
  292.     }
  293. };
  294.  
  295.